Muddyscript, Обновление! Опции

[gamecreator]

ну да

[ChASnock]

ну дык добавьте другой...

... чекбокс (что за каменновечные выражения )

[FBX]

Другой чекбокс с чем? И как его, по-твоему, надо называть?

[ChASnock]

>как называть
Ну хотяб поприличнее, например, флажок, ...
>с чем
... с надписью (и с действиями) "Разрешить изменение карты"

мда , получилось как-то не очень...

[FBX]

а я разве не пофиксил тот баг?

[FBX]

С помощью мутноскрипта воссоздал алгоритм генерации лабиринтов из пещер монстров:

CODE

@generate_lab;
local int,'i';
local int,'j';
loop_up i,1,m_w, //заливка стеной
loop_up j,1,m_h,
set_lev 0,i,j,[get_lev 0,i,j]|gf_wall;
loop_up i,0,m_w:2-1, //инициализация импровизированного массива
loop_up j,0,m_h:2-1,
local int,'n'+i+'_'+j,0;
global int,'count',0;
process_dig 0,target.x-1:2,target.y-1:2;

@process_dig int,int,int; //0,nX,nY - в ужатых координатах
if [v n"v1"_"v2"], break;
local int,'i';
local int,'k';
local int,'bx',v1+1*2;
local int,'by',v2+1*2;
mov n"v1"_"v2",1;
put_object bx,by;
loop_up i,0,3, {
mov k,[select_direction 0,v1,v2];
ifless k, break; //хе-хе, писать if k=-1 недопустимо
if k=0, {
put_object bx,by-1;
process_dig 0,v1,v2-1;
};
else if k=1, {
put_object bx+1,by;
process_dig 0,v1+1,v2;
};
else if k=2, {
put_object bx,by+1;
process_dig 0,v1,v2+1;
};
else if k=3, {
put_object bx-1,by;
process_dig 0,v1-1,v2;
};
};

@put_object int,int; //X,Y - удалить стену в координатах
set_lev 0,v0,v1,[get_lev 0,v0,v1]&(gf_wall)!;

@select_direction int,int,int; //без параметров,возвр.направление
local int,'i';
local int,'c',0;
local int,'lst0',1;
local int,'lst1',1;
local int,'lst2',1;
local int,'lst3',1;
mov v0,-1; //v1 и v2 должны остаться от process_dig
if v1=0, mov lst3,0; else if [v n"(v1-1)"_"v2"], mov lst3,0;
if v2=0, mov lst0,0; else if [v n"v1"_"(v2-1)"], mov lst0,0;
if m_w:2-1=v1, mov lst1,0; else if [v n"(v1+1)"_"v2"], mov lst1,0;
if m_h:2-1=v2, mov lst2,0; else if [v n"v1"_"(v2+1)"], mov lst2,0;
loop_up i,0,3,
if [v lst"i"], inc c;
mov c,[random c];
loop_up i,0,3,
if [v lst"i"], {
if c=0, {
mov v0,i;
break;
};
else dec c;
};

Результат работы:


Прорисовка градиента:

Код

@gradient_floor int,int,int,int,int,int,int; //уровень, R,G,B основного цвета, r,g,b другого цвета
local int,'i';
local int,'j';
local real,'k';
loop_up i,1,m_w,
loop_up j,1,m_h, {
 mov k,[mod i-20]+[mod j-12]:29; //коэфф.интенсивности

 set_lev v0,i,j,[get_lev v0,i,j]&255|(
 v1+[round (v4-v1)*k]+(v2+[round (v5-v2)*k]<8)+(v3+[round (v6-v3)*k]<16)
 <8); //обрезанный цвет смещаем на его место и пристыковываем
};

Результат работы:

[Kislolord]

Сцупер

[ChASnock]

хе-хе, писать if k=-1 недопустимо

А

Код

if k=(0-1)

допустимо?

[FBX]

Да, также допустимо

Код

if k=(-1)

[FBX]

Вот так... убрал отсюда фигню, теперь она обновленная и на сайте.

[FBX]

Новый официальный код респауна объектов. Работать будет в любой версии, хоть и немного некрасиво.

Код

//в начале скрипта
local int,'i';
loop_up i,0,lev_count-1, setup_recreate i;

//в конце скрипта
@setup_recreate int;
mov target,[obj v0,-1,-1,-1,-1];
while 1, {
 mov target,[obj -1,-1,-1,25,-1,target];
 if [cmp target,nil], break;
 mov target.OnDamage,'recreate;';
};
@recreate;
local int,'t',target.t;
if (t=1)|(t=3)|(t=4)|(t=8)|(t=11)|(t=12)|(t=13)|(t=15)|(t=16)|(t=18)|(t=21)|(t=22)|(t=24)|(t=25)|(t=27)|(t=28),
if [pos 'recreate',target.cmd], raise 'У объектов такого типа нельзя размещать recreate в редакторе.';
local obj,'new',[create_obj owner.lv,target];
mov new.act,act_hide;
mov new.wait,400+[random 400]; //настройка времени респауна здесь
mov new.next,target.next;
mov target.next,new;

Карты, не тестировавшиеся именно с таким кодом, в дистрибутив включены не будут, и тем более не будут запущены на сервере.

[FCst1]

А сингл-карт этот скрипт касается?

[FBX]

Он касается респауна, если он по какой-то причине используется в сингле, то да

[ChASnock]

Слыште, запилите-ка свойство объекта OnTick: скрипт выполняется каждый тик

[FBX]

А зачем? Приведи интересный, годный пример, когда это событие вдруг стало бы актуально.

[ChASnock]

Ну просто надо. А когда бы стало актуально событие OnStart? (тем более изменение поля "OnStart" ничего не дает в игре).пардон)

[FBX]

OnStart можно использовать иногда, чтобы не тащить скрипт-файл вместе с картой ради мелких настроек.

Ладно, сделаю. Но я не одобряю такие вещи из-за слишком высокой частоты их вызова - может тормозить начать, хотя это от объема кода зависит.

[ChASnock]

Так как заставить работать настройку платформы "игнор игроков", "игнор монстров" и т.д. (из этих флагов работает только 1 - неразрушимость)? И запили плиз исчо адын флаг: +128 - при нажатии включает препяцтвия (вместо отключения).