Авторские скрипты, Люди, пишите скрипты!!! Опции

[SnoRT]

Женские покруче

Добавлено ([mergetime]1179584860[/mergetime]):
Кансер?

[Гость_Berserker_*]

Бес, я про это и говорил. 4-м пунктом пойдёт w-переменные, а где выбор изменить или просмотреть? Хорошо, я всё же умещу всё в одной менюшке Как, не важно, но работать будет. Завтра вечером (инет такой) выложу.

[Миханик]

Написал скрипт с мифрильной шахтой под номером 92. Что-то подобное уже было, но я попытался максимально приблизить шахту к реальности, чтобы работала, как все остальные. И ещё свою шахту нарисовал. Получилось длинновато, буду оччень рад , если кто укоротит.
**************
Новая версия мифрильной шахты. Ничего не изменилось, зато сюда же всунуты 2 скрипта - шёлк и смена специализации. Возможны лаги, поэтому прозьба нашедших лаги писать. Первооткрывателям плюсы .
линка

[DracoLich]

Обновил скрипт-пак. Пофиксил найденные глюки. Версия 3.6. Скачивать с сайта:
http://dracolich.narod.ru

[DracoLich]

Обновил свой скрипт-пак до 4.0, добавил новый скрипт.
Скачивать с сайта:
http://dracolich.narod.ru/script78.rar

[Bes]

Скрипт преобразования Костяных Драконов в Призрачных, используя арт "Пузырёк с кровью дракона"...
Для срабатывания необходимо:
- открыть окно героя
- иметь в любом слоте только одного Костяного Дракона
- иметь хотя бы один Пузырёк с кровью...

Просто берёте арт и нажимаете на портрете монстра ПКМ.
[удалено, новый код см. здесь]

К сожалению, код пока до конца не проработан...
Я не могу придумать, как поступать, когда игрок возмёт арт (флаг 28 установится в истину), а потом передумает и вернёт его обратно в слот... Надо бы как-то это учесть, но у меня идеи никакой (надо как-то обратно флаг 28 в ноль выставлять)...

Если кто поможет с идеей, буду просто очень благодарен!!!

[DracoLich]

Использовать в продолжении целчка не просто выход
!!FU&y1<>512/y3<>14:E; нажата ПКМ ?
!!FU|y2<68/y2>74:E; слоты 0..6 ?
, а обнулять флаги перед выходом, и все ок.
И функцию можно укоротить:
!?FU150;
!!VRx2&x1<40:Sx1-2;
!!VRx2&x1>39:Sx1 -21;

[Гость_Д'якон_*]

Тогда получается, что при нажатии левой кнопки не на слотах флаги обнулятся, а артефакт не будет положен.

Я не уверен, но мне кажется что нужно делать через функции, т.е. если нажата левая кнопка на одном из слотов и флаг 28 равен 0, то это !?FU1, а если тоже самое но флаг 28 равен 1 то это !?FU2.

т.е.

!?CM2;
!!CM:F?y1 I?y2 S?y3;
!!FU1&-28/y1=0:P;
и т.д.

!!FU2&28/y1=0:P;
!!if|y2=11/y2=12/y2=13/y2=14/y2=20/y2=40/y2=41/y2=42/y2=43/y2=44;
!!IF:V28/0;

НО Я НЕ УВЕРЕН, нужно проверять

[Bes]

да, там ситуация не так то и проста
Я ещё думаю на попытками реализации... спасибо за советы!

Кстати, для ф-ции переконвертации лучше всё же использовать
!?FU150;
!!VRx2|x1=11/x1=12/x1=13/x1=14/x1=20:Sx1 -2;
!!VRx2&x1>39/x1<45:Sx1 -21;

[Bes]

Всё... скрипт вышел из beta-стадии... ура!
Пользуйтесь на здоровие
Поддержка: Феникс-Мод, ТЕ(?)

!?CM2;
!!CM:F?y1 I?y2 S?y3;
!!if&y1=0:;  ЛКМ?
  !!if&y3=12:; нажата?
    !!if|y2=11/y2=12/y2=13/y2=14/y2=20/y2=40/y2=41/y2=42/y2=43/y2=44; Разное1-5 и Рюкзак?
      !!IF&28/-40:V28/0; "полный пузырёк" возвращён?
      !!if&-28/-40:;
        !!FU150:Py2/?y6; переконвертировать № слота
        !!HE-1:A1/?y5/y6; проверить арт
        !!IF&y5=127:V28/1;
      !!en:;
    !!en:;
  !!en:;
  !!if&y3=13:; ЛКМ отпущена?
    !!if&28/40:;
      !!if|y2=11/y2=12/y2=13/y2=14/y2=20/y2=40/y2=41/y2=42/y2=43/y2=44;
        !!VRz1:S^swrdattk.wav^;
        !!HE-1:A3/127/1/1; удалить "пустой пузырёк"
        !!SN:Pz1; озвучка удаления
        !!IF:V40/0 V28/0;
        !!UN:R3/-1; обновить экран
      !!en:;
    !!en:;
  !!en:;
!!en:;
**ситуация "X"
!!if&y1=0/y2=30720/y3=10:;
  !!HE-1&40:A2/127/?y7/d;
  !!HE-1&40/y7>0:A3/127/1/1;
  !!IF&40/y7=0:M^"Пустой" пузырёк не был возвращён герою!
 
  ({конвертация существа отменена})^;
  !!HE-1&40/y7=0:C0/v9/68/1;
  !!IF:V40/0 V28/0;
!!en:;

!?CM2&28/-40; пузырёк взять?
!!CM:F?y1 I?y2 S?y3;
!!FU&y1<>512/y3<>14:E; нажата ПКМ?
!!FU|y2<68/y2>74:E; слоты 0..6?

!!VRy2:-68;
!!HE-1:C0/y2/?y5/?y6;
!!FU&y5<>68:E;

!!IF&y6<>1:Q1/21/65604/4^Для этого действия требуется отряд с одним Драконом...^;
!!FU&y6<>1:E;

!!VRz1:S^trogdfnd.wav^;
!!HE-1:C0/y2/154/1; замена монстра
!!UN:R5/3/0;
!!SN:Pz1; озвучка замены
!!UN:R6/400 R3/-1 R5/4/127;
!!IF:V40/1;  !!VRv9:Sy2;
!!IF:M^Пузырёк пуст!^;

!?FU150;
!!VRx2&x1<40:Sx1 -2;
!!VRx2&x1>39:Sx1 -21;

В принципе, я достиг того, что задумал... Но может кое-что, из преукрасок, в дальнейшем добавлю...
Кстати, сообщение "Пузырёк пуст!" не сильно будет мешать

[Добавлено]
В коде по прежнему имеется два момента, при которых код работает не корректно. Но в силу того, что они мало вероятны, я пока их оставил (попозже попытаюсь и их устанить)

[gamecreator]

если исправить орфографию, то нет

[Гость_Д'якон_*]

остался маленький баг(хотя может и не маленький). После превращения дракона, если пузырь не ставить в слот а нажать им на выход из окна героя, то он появляется опять у героя.

Добавлено ([mergetime]1188927742[/mergetime]):
Нужно наверно запретить выход пока не поставишь пузырь на место

[Bes]

Точно , спасибо! (обоим)

Кстати, там есть ещё один недочёт, но я про него ничего говорить не буду, потому как его можно сделать исключительно с пытливым умом (как у меня ).
Если кто найдёт, то лично от меня будет похвала.



Добавлено ([mergetime]1188933503[/mergetime]):
Только вот как учесть тот момент, когда из окга выходить через Энтер?

[DracoLich]

Выход на энтер считается как нажатие на ОК. Вообще, любая горячая кнопка расценивается как нажатие мышью. так что !?CM работает

[Demiurg]

Выход на энтер считается как нажатие на ОК. Вообще, любая горячая кнопка расценивается как нажатие мышью. так что !?CM работает

Есть косяк в окне встречи героев. Там не детектируется нажатие левой кнопкой мыши на OK.

[Bes]

Используя следующий способ слежения...

Код

!?CM2;
!!CM:F?y1 I?y2 S?y3;
!!IF:M^%Y1 / %Y2 / %Y3
(кнопка / место / как нажато)^;

Я обнаружил для себя (наверняка и для вас тоже), что при нажатии на кнопку "Окей" в окне героя тип нажатия (y3) равен 10 (!)
В справке ничего про это не было сказано, там лишь 12(нажата ЛКМ), 13(отпущена ЛКМ) и 14(нажата ПКМ)!
Это и в 3,58f и в ТЕ!
DracoLich, отметьте этот факт в Справочнике!

Короче, благодаря этому факту я исправил недочёт, описанный Д'яконом
(код исправил, см. пост #186)

[Добавлено]

Ксатати, т.к. у игры есть особенность, из-за которой взятый арт кладётся в слот после окончательного закрытия окна героя, то решение ситуации описанной Д'яконом потребовало несколько извратиться. Поэтому если арт не был положен в слот после переконвертации дракона, конвертация будет отменяться (пока арт всё же не будет положен куда следует, чтобы его в последствии удалить)

[Demiurg]

Ага. Еще один злостный баг ERM. Просто подтип действия редко юзается. !!CM:F хватает сполна. Кстати говоря, данный баг не только в окне героя, а еще и в окне города, как выяснилось.

[Гость_Berserker_*]

Это не баг, а фича. Узнаётся просто и используется для краткой записи щелчка. Удобно и надёжно.

[Fatalist]

А может кто нибудь написать скрипт позволяющий игроку жить без замков неограниченное время. Да и ещё чтобы его можно было активировать в Wog- опциях для любой карты??

[gamecreator]

!#TM40:S1/999/1/255;
!#UN:P800/?50;

!?TM40&50;
!!OW:D-1/128;

скрипт регулируется опцией 800, использует таймер 40 и флаг 50. не исключены конфликты с другими скриптами.