ZVSE
**Помещает глаза вместо Камней знаний и Хижины вместо мельниц. Т.к. функция
**прыгает через несколько объектов, дабы заменить как можно меньше
**(в среднем, как раз 5 и того и того), все равно возможно, что из 2ух камней
**на карте, они оба останутся( Ибо их мало. Юзабелен для больших карт.
!#TM1:S1/1/1/255; - нужен таймер, ибо в PI объекты нельзя заменять
!?TM1;
!!TM1:S1/1/1/0; - деактивация таймера сразу поле срабатывания
!!UN:U100/-1/?y1 U112/-1/?y3; получаем число камней и мельниц

!!UN:X?y-1/?y-2; - получаем размер карты
!!VRy-3:Sy-1 :36 -1; - погрешность для размера карты, (1..4) -1

!!VRy2:Sy1 :5 -y-3; - получить число = 1/5 всех камней + погрешность
!!VRy4:Sy3 :5 -y-3; - получить число = 1/5 всех мельниц + погрешность
!!VRy2&y2<2:S2; - если значение слишком мало, установить 2
!!VRy4&y4<2:S2; - тоже самое

!!DO29887/1/y1/y2&y1>0:P27/100/y1/y2; запустить функцию y1 раз шагом y2, если
**y1 неотрицательно, передать значения x1=номер объекта для вставки (глаз=27),
**x2=заменяемый объект (камень, 100), также передать число объектов (x3) и шаг (x4)
!!DO29887/1/y3/y4&y3>0:P37/112/y3/y4; ^см выше

!?FU29887;
!!VRy-1:S0 R1; - генерация случайного прыжка, чтобы избежать постоянной замены
**одних и тех же объектов (если играется на той же карте)
!!VRx16:+y-1; - добавление прыжка (+0..1)
!!VRy-1:Sx16 +x4; - проверка на некорректное значение номера объекта,
**ибо при шаге >1 возможна ситуация, когда x16>конечного значения функции,
**и ерм выдает немного ошибок
!!VRx16&y-1>x3:Sx3; - фикс превышающего значения
!!FU&y-1>x3:E; - выход при превышаемом значении
!!UN:Ux2/-1/x16/1 Ov1/v2/v3/1 Iv1/v2/v3/x1/0; - найти координаты, удалить старый
**поставить новый

** Просто помещает 6 глаз и 5 хижин в случайные точки карты
!#TM1:S1/1/1/255; - таймер, см в пред примере
!?TM1;
!!TM1:S1/1/1/0;
!!UN:X?y-1/?y-2; получаем размер
!!VRy-1:-1; отнимаем от размера единицу, ибо возможна "посадка" объекта на
**координаты вроде x/108, что выходит за карту,и видно лишь "крышу" объекта
!!DO29887/1/11/1:Py-1/y-2; - запустить функцию 11 раз, передав размер карты x1 и
**x2=0 если нет подземелья, x2=1 если есть

!?FU29887;
!!VRy-1&x16<7:S27; - на первых 6 шагах помещаем глаза
!!VRy-1&x16>6:S37; - на вторых 5 - хижины
!!VRy1:S0 Rx1; - генер (0..x1) координату х
!!VRy2:S0 Rx1; - ^ только y
!!VRy3:S0 Rx2; - генер (0..1), в зависиомти от наличия подземелья, координату уровня
!!UN:Ey1/y2/y3; - проверить, можно ли поместить туда объект. Если флаг 1 истина,
*значит нет. На воде и на Скалы (темнота подземелья) флаг устанавливается истина.
!!VRx16&1:-1; - если тип поверхности вода или подземельная тьма, или поместить
**нельзя, отнять 1 от номера круга.
!!FU&1:E; - и тут же выйти
!!UN:Iy1/y2/y3/y-1/0; -

ZVSE
!?TM2&$day$=1/$once$=1; - день первый, первый активный игрок
!!UN:U100/-1/?y-1 U112/-1/?y-2; - получаем число камней и мельниц
!!VRy-3:Sy-1:5;!!VRy-4:Sy-2:5; - получаем число = 1/5 всех объектов
!!VRy-3&y-1<2:S2;!!VRy-4&y-4<2:S2; - если объектов слишком мало, установить кол-во заменяемых на 2
!!DO29887/1/y-3/1&y-1>1:P27/100/y-1; - пропуск значений в функцию, запуск
!!DO29887/1/y-4/1&y-2>1:P37/112/y-2; -//-
!?FU29887;
!!VRy1:Sx3-1; - отнимаем единицу от кол-ва для корректной генерации номера
!!VRy2:S1 Ry1; - генерируем случайный номер объекта
!!UN:P904/1 P905/0; - отключаем вывод сообщений об ошибке
!!UN:Ux2/-1/y2/1; - находим (или пытаемся найти) координаты объекта
!!UN:P904/0 P905/?y3; - проверяем, есть ли ошибка (объект уже заменён, а его номер сгенерирован повторно)
!!VRx16&y3>0:-1; - если ошибка - отнять 1 от кол-ва кругов функции
!!FU&y3>0:E; - и тут же выйти
!!UN:Ov1/v2/v3/1 Iv1/v2/v3/x1/0; уничтожить объект, поставить новый