в редакторе есть специальное дерево что может загораться. его и надо ставить

gamecreator А по конкретнее можно? Какое это дерево?
DracoLich Там стоят дубы-колдуны

редактор карт - города - полоса из деревьев (типа до и после), перед огненной стеной

Блин, а этот ERM затягивает
Уже второй день пошёл, как я начал с ним экспериментиовать.

Пара вопросов начинающего...
1 - Диалог с вариантами ответов. Как сделать, чтобы применять нужный скрипт к конкретному ответу ( "Да" или "Нет")
2 - Можно ли, чтобы при получении арта он сразу "одевался героем" (например, сапоги - на слот "ноги"), а не помещался в рюкзак?
3 - Пробовал сделать передвижение своб. монстра через "добавить объект" и "удалить объект" - не получилось (выдаёт ошибки). Может кто подскажет как сделать это, ведь у героя же есть телепортация (!!HE-1:P;).
4 - как добавить отряд монстров к войскам героя, сделав им низкую мораль(-2 например) (а в определённый момент убрать этот недуг, т.е. чтобы как у всех)
5 - Как дать в нужный момент герою коммандира, причём со своим именем. А потом обратно его убрать.
6 - Как запретить повторное выскакивание диалога (да и вообще скрипта)
7 - удаление объект... Если объект занимает более чем одну клетку на карте (например, 4 клетки), то при его удалении достаточно будет указать координату любой из четырёх клеток, да?
8 - вопрос. А нельзя ли писать скрипт непосредственно в событии?
Или это как-то разрешить делать?
9 - Что надо добавить в скрипт "убить героя", чтобы при исчезновении героя сразу появлялось сообщение о проигрыше (ну и естественно чтоб пошёл ролик про гельятину)

1) При каждом вопросе, заданном с помощью !!IF:Q...2^Вопрос^; после Q идет номер флага, куда занесется ответ. Например:
!!IF:Q2^Первый вопрос^; где 2 - номер флага, читай ERM-хелп на русском (моя подпись)
!!IF&-2:M^Вы ответили отрицательно, флаг 2 теперь отрицателен^;
!!IF&2:M^Вы ответили полоэительно, флаг 2 теперь положителен^;
2) Для одевания арта автоматически, + добавления заклинаний артефакта, используй команду !!HE#:A4/#1; где # - номер героя, а #1 - артефакта.
Например, оденем Альянс Ангелов:
!!HE-1:A4/129;
Если бы мы использовали команду !!HE-1:A129; арт поместился бы в рюкзак, + команда !!HE-1:A1/129/3; (поместить альянс в правую руку героя) не давала бы бонусов герою. В общем, используй !!HE-1:A4/129;
3) В чем ошибка? Чисто мое мнение - перемещение монстров ненужныая вещь, из-за отсутствия анимации как таковой. А телепортация - фигня... !!UN:Ox/y/l; - удаляешь монстра, !!UN:Ix/y/l/54/номер_монстра; - ставишь монстра, x y l координаты
4) Редактировать мораль одному стеку героя нельзя, только самому герою. Нету ресейверов для морали и удачи в битве.
5) Насколько я понял, в начале игры нужно отключить командиров, чтобы игрок не имел его. После триггера на то место, где герой должен получить командера, пишем:
!!CO-2:E1;
!!CO#0;, где # - номер героя (-1 для посетителя)
Со своим именем:
!!CO#:N$; - где # - номер героя (-1 для текущего), $ - номер z-переменной с именем командера
Убрать обратной операцией:
!!CO#1; где # - номер героя (-1.. понятно, короче)
!!CO-2:E0;
6) Ставить флаг или переменную для контроля, например
!?OB1/1/0; - при посещении объекта в 1/1/0
!!IF&40:M^Вы уже здесь были^; - если флаг 40 = Истина, то показать это сообщение..
!!FU&40:E; - не выполнять дальнейший скрипт, если флаг 40 истина (т.е. объект уже был посещен)
!!IF&-40:M^Вы посетили этот объект, и больше здесь ничего не будет!^; - при первом посещении (флаг 40 всегда установлен на Ложь в начале карты)
!!IF:V40/1; - установка флага 40 на Истина
7) При удалении - желательно удалять желтый квадрат (для посещения который), если его нету - нижний правый квадрат объекта
8) В каком событии?
9) Строку
!!UN:Q0/1; - немедленно проиграть

Добавлено ([mergetime]1169124817[/mergetime]):
1) При каждом во%

Уважаемый DracoLich обьясните пожалуйста почему не работает следующий скрипт?
ZVSE
!?OB9/14/1;
!!IF&v64=0:Q1/8/53/8/98/8/7/10^ХХХ.^;

!!IF&v1=1:Q1/21/72/21/73/1^ХХХ^;
!!HE-1&v1=1:T9/14/1/72/5;
!!HE-1&v1=1:A79;
!!IF&v1=1:Q1/8/79^ХХХ^;


!!IF&v1=2:M^ХХХ^;
!!HE-1&v1=2:W>=400;

!!IF&v1=0:Q1/8/7/1^ХХХ^;
!!HE-1&v1=0:K;

!!IF&v64=1:M^Уходите^;
!!VRv64&v64=0:S1;
Точнее почему не дает артефакт. И при повторном посещении выдает два сообщения.
И еще разве нельзя в сообщении скрипта !!IF:Q поставить картинку например внешнего жилища (blooddragon)?

!?OB9/14/0;
!!IF&v64=1:M^Уходите^;
!!FU&v64=1:E;
!!IF:Q1/8/53/8/98/8/7/10^XXX^;
!!IF&v1=0:Q2/8/7/1^XXX^;
!!HE-1&v1=0:K;
!!IF&v1=1:Q2/21/72/21/72/1^XXX^;
!!HE-1&v1=1:O?v2 T9/14/1/72/5 O?v3;
!!FU&v1=1/v2<>v3:E;
!!HE-1&v1=1:A4/79;
!!IF&v1=1:Q2/8/79/1^XXX^;
!!IF&v1=2:M^XXX^;
!!HE-1&v1=2:W400; - непонятно, что сделать с очками хода героя. Изменить? Установить? Я установил на 400
!!VRv64:S1;

Добавлено ([mergetime]1169166814[/mergetime]):
Картинку - низзя. ТОлько внутриигровые, и указанные в ERM-помощи

DracoLich, вы мой "сан-сэй". Я перед вами в неоценимом долгу... просите чего хотите


В синем кружочке... Ну например, я впишу в него скрипт, а в таймерах-событиях прописать ещё какой-то скрипт, чтоб он исполнял скрипты из синих кружков. Вот что я имел ввиду.
А то постоянно см. координаты для кружков - это напрягает...

А эту строчку надо прописывать выше чем диалог, или это не принципиально важно?


А как написать эту переменную. Я ж токо учусь, и совершенно не знаю как надо синтаксически прописывать z-переменные...



... и вот ещё пара вопросов "из не понятого":
10) - Как задать имена для пустых объектов, у которых только есть object №# (тоже и для пустых артов+задать прибавку к первич навыкам)
11) - как задать нужное кол-во создаваемого на карте монстра-нейтрала, если его добавлять так.. !!UN:I65/64/1/54/6;
12) - как понизить мораль героя (раз ж с конкретным отрядом нельзя), а потом её опять вернуть в дефолт...
13) - как отключить действие объекта, которое происходит "по умолчанию". (например, чтоб у могилы не предлагалось обыскать её)
14) - как удалить конкретный отряд из войска Героя
15) - как при уменьшить текущий показатель MP героя (ну чтоб шкала опустилась, но не макс. величина) на определённую величину (ну или на половину от имеющегося). Я попробовал !!HE-1:W; - но это съело весь показатель MP.
16) - как задать выйгрыш на определённое событие
17) - какое имя анимашки для горящего города (для Замка), ну или как скриптом доджечь город. Просто я думал удалением-вставкой сделать это. Но вдруг есь и др. способ.
18) - как отключить работу чит-кодов. Я пробовал через !#UN:P77/0;, но это не сработало. Это только отключило меню "Cheat", а коды через TAB всё равно вводились.
...

1) По другому никак. Каждый скрипт должен лежать в Событиях либо в спец. файле с картой
2) Принципиально! Ведь ERM выполянет все команды построчно, так что если вы перенесете строку на начало, фактически будет считаться, что вы уже посещали объект, ведь флаг уже установился на истину!
3) Ресейвером
!!VR@:S[^^];
Например, установим переменную v1 на 10:
!!VRv1:S10;
А для текстовых сообщений пользуем "степень" (не помню, как они правильно называются ))), установим переменную z1 в текст:
!!VRz1:S^Текст^;
Настоятельно рекомендую прочитать первые страницы либо мою помощь, там ПОДРОБНо рассмотрены операции с переменными в спец. разделе.
...
10) Все новые пустые объекты (находящиеся в разделе "города" в редакторе карт) описаны в ERM-помощи, там их вид и номер. Одно скажу точно - у них всех тип = 63, а подтип варьируется далеко.
11) Командой UN помещаете монстра, командой MO редактируете его, например, установим кол-во монстров. Синтаксис таков:
!!MOx/y/l:G$; - монстр в x y l, $ = кол-во.
!!MO65/64/1:G100; - пусть будет 100 монстров в отряде.
12) Командой !!HE#:R0/$;, где # - номер героя (-1 = текущий), $ - показатель морали. Установим его на -3:
!!HE-1:R0/-3;
Устанавливается показатель ВСЕГДА до первой битвы, дальше сбрасывается. Так что придется после после каждой битвы ставить снова, если нужно
13) !!OBx/y/l:S; - координаты пояснять нужно?
14) Непонятная формулировка - отряд или стек. Т.е. существ либо именно слот в окне героя... Вообще удалить отряд можно так:
!!HE#:C0/#1/$2/$3; - где # - номер героя, #1 - номер слота (0...6), $2 - тип монстра (для удаления используем -1), $3 - кол-во монстра (если удаляем, то ставим 0 для избежания глюков)Итак:
!!HE-1:C0/0/-1/0; - удалить первый стек героя
Удалить особое существо. Нужно знать номер существа, итого получаем синтаксис:
!!HE#:C1/#1/$2/$3; - принимаем этот синтаксис за синтаксис изменения кол-ва существ, тогда пояснения будут следуюшие: # - номер героя (-1 опять же...),#1 - номер искомого монстра, $2 - еще раз номер искомого монстра (либо d), $3 - здесь пишем запоминание кол-ва существ, т.е. переменную. Пример:
!!HE-1:C1/0/d/?v1; - теперь в v1 содержится общее кол-во пикейщиков героя, для сравнивания используем синтаксис
!!IF&v1>10:M^У вас больше 10 копейщиков!^;
!!IF&v1<10:M^У вас меньше 10 копейщиков!^;
!!IF&v1=10:M^У вас 10 копейщиков!^;
И т.д. Настойчиво рекомендую прочитать мою статью "Флаги и переменные"!
Теперь отнимаем нужное кол-во следующим образом:
!!HE-1:C1/0/d/d-x; - где х - число монстров для удаления. Если оно больше существующих у героя, отнимется только существующее кол-во, и никакого сообщения об ошибке не появится.
15) Командой !!HE#:W$;, где # - понятно что, а $ - кол-во МР героя. Для изменения (не установки) кол-ва МР используем следующий синтаксис: Отнимем 150 МР у героя:
!!HE-1:Wd-150; - все понятно? Получить половину от его текущих ходов можно командой получения значения в переменную (?@, где вместо @ - переменная), затем разделить ее на 2 (!!VR@::2;), и отнять (!!HE-1:Wd-@
16) Событие - кругляш?
!?LEx/y/l;
!!UN:Q1; - все ОК?
17) Изменение состояния города:
!!CAx/y/l:I#; - где координаты, думаю, уже все запомнили, а # - степень разрушенности (0 - нормальный вид, -1 - полностью разрушен, 1 - разрушен немного, 2 - больше, 3 - сильно рарушен)
18) Никак. Это никак ERM не котируется.
И все же, обязательно каждый должен иметь мой хелп! Там же все написано по русски...

DracoLich спасибо. А можно сделать так, чтоб герой улучшал не только двоих, но и больше существ (например лучников, импов, крестоносцев, гогов в монахов)?

нет

Вроде можно.

Используя изменения спец. героя - максимум два существа могут быть улучшены в другое. Используя извращения с нажатиями мыши - и больше

Народ, а как реализовать перемещение камеры в карте приключений... ну типа я говорю с кем-то (в диалоге), как только он кончается, камера прыгает на объект про который я токо узнал из разговора... а потом назад, к герою.

И ещё, можно ли насильно менять радиус обзора героя, на определённый момент, а потом опять в дефолт?

Thanks! Ж)

Поменять радиус обзора невозможно..
Прыг камеры:
!!UN:Lx/y/l/$; - где координаты, а $ - время задержки камеры на точке (в мс.). Обратно прыгай той же командой, только с другими параметрами (обычно я ставлю задержку 1 при обратном прыжке)

А если например, на время дать навык разведки эксперта, а потом, в нужный момент убрать его?

Да кстати, насчёт артов героя, можно ли дать герою арт, но чтоб его не было видно в окне Героя (и чтоб слот не занимал), а его действие оставалось?
И ещё... нельзя ли запретить перетаскивания (и объединения одинаковых) монстра в др. стэк в войске. Т.е. закрепить за ним его, это чтоб прописывать в скрипте одну и тужу координату стэка. А то мало ли, игрок захочет поменять расстановку в армии, а я получится в скрипте ссылаюсь на пустышку... Если нельзя, то хотябы, сделать возврать к расстановке некоторых слотов армии при закрытии окна Героя игроком. Ну типа он поменял, закрыл с чистой совестью, а оно хоп и назад вернулось...

Это можно таймером:
...здесь должен быть нужный триггер
!!VRy1:Sc;
!!VRy2:Sc+2; - +2 означает, что разведка заберется через 2 дня
!!OW:C?y3;
!!VRy3&y3=0:S1; - установка игрока для таймера
!!VRy3&y3=1:S2;
!!VRy3&y3=2:S4;
!!VRy3&y3=3:S8;
!!VRy3&y3=4:S16;
!!VRy3&y3=5:S32;
!!VRy3&y3=6:S64;
!!VRy3&y3=7:S128;
!!TM7:Sy1/y2/y2/y3; - установка таймера для игрока
!!HE-1:N?v5000 S3/3;
!?TM7;
!!HEv5000:S3/0;

Дать невидимый арт нельзя, нео почему бы не воспользовать простым изменением навыков?
!!HE-1:F$1/$2/$3/$4; - где $1...$4 соответственно атака, защита, сила, знания. используйте d+$, чтобы добавить значение $, d-$, чтобы отнять, и $, чтобы установить.

Рекомендуется отнимать не стеки, а именно существ. Закрепить за монстром место можно, но долго и много. Отнимайте существ, как я понял, именно это здесь и нужно...
!!HE-1:C1/номер_существа/d/d-$; - где $-кол-во для отнимания (чтобы забрать всех, используйте синтаксис !!HE-1:C1/номер_существа/-1/0;)

А как изменить свойства сундука сокровищ?

Всмысле, золото и опыт?
!!CHx/y/l:B$; - $ = показатель кол-ва золота, *500. Т.е. 1 = 500 золота, 2 = 1000. Опыт всегда равен $*500 -500, т.е. при $=1 он будет равен 0

Так-с...
Предложения:
1) Тем кто задаёт эти полунубские вопросы: перемещаем взгляд на подпись Драколича, находим вторую по счёту строчку (считайте хоть сверху, хоть снизу), на неё нажимаем, ждём 10 минут и сразу получаем ответы на тысячи вопросов. Доходчиво?
2) Модерам: если меня не обманывают глаза, то это тема для обучения. Надо её почистить, а вопросы задавать в темах "Вопросник", "Если нужен скрипт".

У меня есть ещё пара тройка вопросов (надеюсь я вас не задолбал )...
a - можно ли удалять ландшафт с карты (я хочу в определённый момент убрать проклятую землю и взамен установить святую)... если да, то как?
b - как установить бесконечное обнуление MP героя, чтоб при наступлении нового дня у него опять было 0. Я так собираюсь как бы проучить героя, если он зайдёт туда, куда не следовало.
с - как зациклить перемещение объекта монстра по карте. Например у меня есть 6 точек, по которым будет как бы идти монстр, а мне надо чтоб это перемещение повторялось снова и снова (не буду же я повыторять этот цикл скриптов до бесконечности, яж не настолько безумен). У меня так будет реализован процесс работы на шахте...
d - можно ли установить на карте "крестик" после определённого действия, а потом опять его убрать. Я так кочу пометить место сбора... Если так нельзя сделать, то может реально насильно (без желания игрока) открыт карту-загадку и там уже будет виден "крестик" (а я у нужном месте грааль положу)

По поводу невидимого арта... это я хотел не для навыков героя, а чтоб исключить возможность побега противника (эффект "оков войны").
И ещё... у меня почему-то на карте противник имеет командира, я же запретил их для всех - !#UN:P6/1; Что за дела? (Противник - Розовый)

СПАСИБО!

Запретить командера нужно командой
!#UN:P3/1;
либо
!#CO-2:E0;
a) Помойму, нельзя убрать. Да и поставить проблематично
б) Ставить таймер, и каждый день проверять на условие, при котором обнуление должно сработать. например:
!#TM10:S1/999/1/255;
!?TM10;
!!**:*?y1; - здесь должно быть условие, практически любое
!!HE#&y1=$:W0;
Здесь каждый день герой # будет обнулен по МР, если переменная-проверка = $.
в) Использовать синтаксис FU:
!?...; Триггер, можно таймер
!!DO1/1/1/1:P; - скрипт повторится 1 раз, если нужно больше - меняем третью единицу на нужное кол-во повторов.
!?FU1;
Здесь прописываем помещение и удаление монстра по координатам командами UN:O и UN:I
Вот и все.
г) Нельзя ни показать Грааль, ни крест поставить, ни вообще проводить операции с картой раскопок. Обычно я помещаю какого-нибудь монстра в нужное место...

Добавлено ([mergetime]1169387827[/mergetime]):
Кстати, что на Aleee, что на мой пост - два нуля внимания.

1)Как проверить монстра на позиции?
2) Уже писал в "Если нужен скрипт" но там отвечать не хотят Какой должен быть скрипт с таймерами на каждый день недели? Например существо в понедельник стоит на позиции x/y/i во вторник на x+1/y+1/i.
И нужно ли будет прописывать ему название и описание для каждой новой точки?
Буду очень признателен!

Вот ещё вопрос. Как проверить, сколько у героя армии в каком слоте, ввести в переменную имя существа, его кол-во (письменную)

2 Secro
1) !!OBx/y/l:T?y1 U?y2; - если на позици монстр, то y1=54, а y2=тип монстра
2) Здесь очень сложно проработать механизм передвижения существа, чтобы только раз в ход. Но можно использовать Движение монстров:
!#MW:Px/y/l/#/$; - генерировать бродячего монстра на позиции x/y/l,# содержит подтип монстра, $ - его уникальный номер.
!#MW$:A2/x/y/l; - установить точку назначения монстру $ в xyl
2 Lion
!!DO1/0/6/1:P;
!!IF:M^%Z-1 %Y-1
%Z-2 %Y-2
%Z-3 %Y-3
%Z-4 %Y-4
%Z-5 %Y-5
%Z-6 %Y-6^;
!?FU1;
!!HE-1:C0/x16/?y1/?y2;
!!VRy3&y2>1:S1;
!!VRy3&y2=1:S0;
!!VRy4:Sx16 *-1 -1;
!!VRyy4:Sy2;
!!UN&y1>-1:N3/zy4/y1/y3;
!!VRzy4&y1=-1:S^Никого^;

Ну хоть убей не получается! Игра вылетает сразу даже не загрузившись.
Сделал по другому но одна малина, вот скрипт
ZVSE
!?LE11/3/1;
!!MW6:P16/12/1/1;
!!MW6:A1/18/10/1;

Кстати, что означают символы <>, что-то я их не увидел на первой странице (а может не заметил )

не равно

В обеих командах неверный синтаксис, нужно в таком случае !!MW6:P16/12/1/1/6; - поместить бродячих алебардистов в 16/12/1, затем
!!MW6:A2/1/18/1; - указать им точку назначения. Откуда взялось A1 - непонятно

2Dracolich
Спасибо! Лови плюс!
И еще смотри вроде бы такой простой скрипт но!

!?OB33/20/1;
!!OB32/18/1:E0;
!!TR32/18/1:P1;
!!IF&v91=0:Q1/22/18/8/13/10^Вы совсем забыли потушить костер! Ведь может начаться пожар! Вы хотите набрать воды?^;
!!IF&v91=1:M^Вы набираете пару ведер воды из озера.^;
!!IF&v91=1:V66/0;
!!IF&v91=1:V65/1;
!!IF&v91=2:M^Зачем возвращаться? Нам предстоит еще такой длинный путь!^;
!!IF&v91=2:V65/0;


!?OB32/18/1; - проверим, посещается ли объект
!!IF&v65/-66:M^Вы тушите костер и разбрасываете поленья. Теперь точно ничего не случиться.^; - показать это сообщение, если флаг №65 - истина и 66 - ложь
!!UN&v65/-66:O32/18/1;


При запуске вылетает ошибка:
ERM syntax Error.
File:erm
Line:5412
Reason:
"GetFlags" -cannot set or get second argument in "&..." part(only check)
и скрипты отключаются...

Ошибка выделена жирным шрифтом. Как я понял, нужен ФЛАГ, а не переменная v65, т.е. нужно так:
!!IF&65/-66:M^Ля-ля-ля^;
!!UN&65/-66:O32/181;

Выдержка из справки...

Т.е. какую надо проставлять цифру взамен $, не совсем понятно...

Мне вот надо сделать это..
, а я не знаю как прописать вражеского героя,.. толи через цвет игрока (128), толи через номер игрока (7), толи через имя героя (69), толи через тип командира (8).. в общем подскажите, что в спарвке имелось ввиду!

Эта цифра - номер героя, у которого этот командир. Т.е.:
!!CO69:T8 N2; - у героя ИСРА.

Помогите плиз, Как сделать так, чтобы перед посещением обьекта, у героя перед битвой менялась армия на 1-го чемпиона, а после чемпион исчезал и появлялась та армия, которая у него была?

Перед битвой:
!!HE-1:C0/0/?v11/?v21;
!!HE-1:C0/1/?v12/?v22;
!!HE-1:C0/2/?v13/?v23;
!!HE-1:C0/3/?v14/?v24;
!!HE-1:C0/4/?v15/?v25;
!!HE-1:C0/5/?v16/?v26;
!!HE-1:C0/6/?v17/?v27;
!!HE-1:C0/0/-1/0;
!!HE-1:C0/1/-1/0;
!!HE-1:C0/2/-1/0;
!!HE-1:C0/3/-1/0;
!!HE-1:C0/4/-1/0;
!!HE-1:C0/5/-1/0;
!!HE-1:C0/6/-1/0;
!!HE-1:C0/0/11/1;

После битвы:
!!HE-1:C0/0/v11/v21;
!!HE-1:C0/1/v12/v22;
!!HE-1:C0/2/v13/v23;
!!HE-1:C0/3/v14/v24;
!!HE-1:C0/4/v15/v25;
!!HE-1:C0/5/v16/v26;
!!HE-1:C0/6/v17/v27;

Можно скрипт раза в три сократить... И он не учитыват опыт монстров (вдруг таковой на карте включен)... Сегодня уже нету времени, а завтра если раньше меня никто не нарисует напишу...

Люди, как поставить скриптом "событие"?
!!UN:Ix/y/I/26/d; не работает!

Dracolich слушай за что отвечают эти строчки:!!HE-1&v9<>-5:A2/83/?v9/d; ты мне их написал. Насколько я понимаю для проверки на арт, но почему именно 9<>-5? Что это? И если я вставлю эту же строчку в другой но похожий скрипт то онработает не совсем правильно... Точнее после исполнения одного скрипта(квеста) другой просто не дается!

Локальное событие:
!!UN:Ix/y/l/26//1;
Если его не настроить, то оно может служить разве что триггером.
Чтобы задать свойства используй !!LE.

А где я это писал?

Для одного скрипта с проверкой артефакта:
ZVSE
!?OB20/14/1;
!!HE-1&v9<>-5:A2/20/?v9/d; - проверяем наличие артефакта 20, причем только если v9 не равна -5
!!IF&v21=1/v9=0:Q11/8/20/1^ХХХХ^; - если это не первое

посещение, и артефакта нет, выводим это сообщение
!!IF&v21=0/v9=0:Q10/8/20/1^ХХХХ^; - если это первое сообщение, и арта нет,

выводим это сообщение
!!IF&v9>0:M^ХХХХ ^; - если артефакт присутствует, выводим это сообщение
!!HE-1:A-20;
!!HE-1&v9>0:W0;
!!VRv9&v9>0:S-5;

!!VRv21&v21=0:S1; если первое посещение, установить, что оно уже было

Мне интерестно все, что написанно выше и можно ли проверить несколько артов сразу?

ну так там же написано: если v9 не равно -5, тоесть v9<>-5.
<> - это аналог !=

Блин... Ну можете мне на пальцах чтоли обьяснить... За, что отвечает v9<>-5
Почему именно -5 а не -6?
Не понимаю...
Я хочу вставить этот же скрипт в другой квест.

Потому что я устанавливаю
!!VRv9&v9>0:S-5;
на -5, чтобы ты не мог подходить снова и снова и получать награду снова и снова

Получается для вот этого скрипта:
!#VRz610:S^ХХХХ^;
!#VRz607:S^ ХХХХ^;
!#VRz608:S^ ХХХХ^;
!#VRz609:S^ ХХХХ^;
!#OB20/20/1:S;
!?OB20/20/1;

!!IF:G1/501/1/610/607/608/609/0/0/0/0/0/0/0/0;
!!IF&v501=1:M^ХХХХ^;
!!IF&v501=2:M^ХХХХ^;

!!IF&v501=4:Q1/20/7/9/44/10^ХХХХ^; здесь дается на выбор навык или заклинание.
!!HE-1&v1=1:S1/2;
!!HE-1&v1=2:M44/1;
!!VRz610&v501=4:S1;
Тоже можно задать чтобы нельзя было оба бонуса получить(навык или закл.)? Подскажи куда и какую строчку вставить. У меня стоит только запрет вторичного посещения. А на пробел срабатывает.

а как же это сделать? Подскажи плиз, Druin. Я другу помогаю с картой (и себе), а такой скрипт трудно запомнить...

to Serco
Что-то я не вижу запрета второго посещения... На всякий случай, чтобы нельзя было второй раз войти через пробел, вставляешь такую строчку:
!!VRv5:S1;
а в триггере делаешь проверку &v5=0.

Если нужно запретить именно диалоговое окно с выбором навыка и заклинания, то тоже самое делаешь, но условие ставишь на !!IF&v501...

Угу, тады даже если тебе нифига не дадут, кроме собсно задания, ты уже не сможешь посещать объект. Нужно ставить контрольную переменную после выполнения условий, а не так, как у тебя

Понятно, что всё завсисит от объекта. Но если он линейный, то именно так.

Так в теме "Если нужен скрипт" зачастую просто не отвечают поэтому спрошу здесь.
Господа послушайте, может кто-нибудь сделатьскрипт, чтобы при посещении события срабатывал таймер, скажем в первый день (после посещения) удалялся один обьект, во второй другой и так до... нужного
Заранее благодарен. У меня, что-то не получается

А как можна сделать диалоговое окно в котором игрок сам вводит ответ (пример - сфинкс)?

не дублируй посты
и вообще глупость предложил

да